Экспорт данных из 1С в Excel

Как данные из 1С сохранить в таблице XLS или XLSX?

//функция создаёт новую книгу в MS Excel и выгружает табличную часть заданного документа
Процедура гМногострочка_Экспортировать(Док) Экспорт
     //документ
     Д=СоздатьОбъект("Документ");
     Д.НайтиДокумент(Док);
     //приложение
     Оле=СоздатьОбъект("Excel.Application");
     Если ФлагВидимость=1 Тогда
          Оле.Visible=1;
     КонецЕсли;
     Книга=Оле.Workbooks().Add();
     Книга.Windows(1).Caption=Д.ПредставлениеВида()+" "+СокрЛП(Д.НомерДок);
     Лист=Книга.Activesheet;
     //шапка
     Колонка=0;
     Для i=1 По Метаданные.Документ(Д.Вид()).РеквизитТабличнойЧасти() Цикл
          Ж=Метаданные.Документ(Д.Вид()).РеквизитТабличнойЧасти(i);
          //колонка
          Колонка=Колонка+1;
          Ячейка=Лист.Cells(1,Колонка);
          //текст
          Ячейка.Value=Ж.Идентификатор;
          //форматирование
          Ячейка.Font.Bold=1;
          Если Ж.Тип="Число" Тогда
               Попытка
                    Лист.Columns(Колонка).NumberFormat="# ##0.00";
               Исключение
                    Лист.Columns(Колонка).NumberFormat="# ##0,00";
               КонецПопытки;
          КонецЕсли;
     КонецЦикла;
     //строки
     Д.ВыбратьСтроки();
     Пока Д.ПолучитьСтроку()=1 Цикл
          Лист.Range("A"+Число(Д.НомерСтроки+1)).Select();
          Колонка=0;
          //многострочка
          Для i=1 По Метаданные.Документ(Д.Вид()).РеквизитТабличнойЧасти() Цикл
               Ж=Метаданные.Документ(Д.Вид()).РеквизитТабличнойЧасти(i);
               Колонка=Колонка+1;
               //значение
               Значение=Д.ПолучитьАтрибут(Ж.Идентификатор);
               Лист.Cells(Д.НомерСтроки+1,Колонка).Value=СокрЛП(Значение);
          КонецЦикла;
     КонецЦикла;
     //авто подбор ширины
     Лист.Cells.EntireColumn.AutoFit();
     //закрепление области
     Лист.Range("A2").Select();
     Оле.ActiveWindow.FreezePanes=1;
     Оле.Visible=1;
КонецПроцедуры

Реклама:
Смотрите также:
Учёт комиссионной торговли в программе 1С
Порядок сортировки, установленный в базе данных, отличается от системного?
Отчёты администратора для обслуживания 1С
Скачать программы для 1С